ZTISelectBootDisk.wsf

Thought I would post this script, I get asked about it now and then.

MDT works pretty well when there is only one hard disk on the client machine, and it will also work fine if we can assume that the first disk (disk 0) is the correct target for the OS.

The default Task Sequence is setup by default to target the first disk (Disk 0). Administrators can change the Task Sequence to target other disks, say the second disk (Disk 1), but then *all* installations for that task sequence will target the second disk.

The Problem

This model breaks down in more complex environments where there is more than one disk *and* the order of the disk is non-deterministic. Say for example you have a server, one disk is 300GB and is connected to the SATA bus, and another 8 disks are 1TB drives connected to a RAID SAS controller.

The order of the disks (disk 0 through disk 8) could change depending on the load order of the storage drivers. Depending on the timing, Disk 0 could come up first, or could come up last, there is no way to force the disk ordering. So if we want to target a specific disk we need to change MDT.

OSDDiskIndex

The trick to targeting a different disk is within the Default Task Sequence, the “Format and Partition Disk” step is applied against a specific target disk, in this case it targets the first disk (disk 0) by default. The variable used to specify the target disk for the ZTIDiskPart.wsf script is OSDDiskIndex. This variable is stored within the ts.xml Task Sequence configuration file and is only visible to that step in the task sequence. If we were to define OSDDiskIndex as a global variable in a script, it would override the local task sequence definition.

Getting the Disk Index

The trick is to find a consistent and repeatable way to find our target disk, in the server example above we could search for all drives that are less than 500GB. In my environment at home, I use Intel SSD Drives as the OS Drives, and spinning disks for storage, so I could do a search for “Intel SSD*”.

In VBScript we perform a search for disks using a WMI Query. Use Powershell to help prototype your query to get it just right. For example here is a search for all disks whose model starts with “Intel SSD”:

C:\>powershell
Windows PowerShell
Copyright (C) 2012 Microsoft Corporation. All rights reserved.

PS C:\> gwmi win32_diskdrive -filter 'model like "INTEL SSD%"'

Partitions : 3
DeviceID   : \\.\PHYSICALDRIVE0
Model      : INTEL SSDSC2BW240A3L
Size       : 240054796800
Caption    : INTEL SSDSC2BW240A3L

Sample

Here is a sample I wrote to set the OSDDDiskIndex variable based on a WMI Query. You must set the OSBootDiskOverrideWQL variable somewhere, perhaps in the customsettings.ini file.

<job id="ZTISelectBootDisk">
	<script language="VBScript" src="ZTIUtility.vbs"/>
	<script language="VBScript" src="ZTIDiskUtility.vbs"/>
	<script language="VBScript">

' // ***************************************************************************
' // 
' // Copyright (c) Microsoft Corporation.  All rights reserved.
' // 
' // Microsoft Deployment Toolkit Solution Accelerator
' //
' // File:      ZTISelectBootDisk.wsf
' // 
' // Version:   <VERSION>
' // 
' // Purpose:   Given a collection of Storage Devices on a machine,
' //            this program will assist in finding the correct 
' //            device to be processed by "ZTIDiskPart.wsf"
' // 
' // WARNING:   If there are any *other* disks that need to be Cleaned
' //            and formatted, they should be processed first. 
' //            And this the global Variable OSDDiskIndex should be
' //            set to <blank> when done being processed by ZTIDiskPart.wsf.
' // 
' // Variables: 
' //   OSDDiskIndex           [ Output ]  - Disk Index
' //   OSBootDiskOverrideWQL              - WMI Query Language for Win32_DiskPartition  
' //      " WHERE Size < 100000000000 and InterfaceType = "IDE"  and MediaType != "Removable Media""
' //      " WHERE Model like "INTEL SSD%""
' //
' // Usage: 
' //   cscript.exe [//nologo] ZTISelectBootDisk.wsf [/debug:true]
' //   cscript.exe [//nologo] ZTIDiskPart.wsf [/debug:true]
' //   cscript.exe [//nologo] ZTISetVariable.wsf [/debug:true] /OSDDiskIndex:""
' //
' // ***************************************************************************

Option Explicit
RunNewInstance

'//----------------------------------------------------------------------------
'//  Main Class
'//----------------------------------------------------------------------------

Class ZTISelectBootDisk

	'//----------------------------------------------------------------------------
	'//  Main routine
	'//----------------------------------------------------------------------------

	Function Main

		Dim oWMIDisk
		Dim bFound
		Dim oDiskPartBoot

		oLogging.CreateEntry "---------------- Initialization ----------------", LogTypeInfo

		IF oEnvironment.Item("DEPLOYMENTTYPE") <> "NEWCOMPUTER" Then
			oLogging.ReportFailure "Not a new computer scenario, exiting Select Boot Disk.", 7700
		End If

		bFound = FAILURE

		''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
		'
		'  1st Pass - Find any disk that matches the Query  "Select * From Win32_diskPartition %OSBootDiskOverrideWQL%"
		'

		If oEnvironment.Item("OSBootDiskOverrideWQL") <> "" then
			oLogging.CreateEntry "Search for: [ " & oEnvironment.Item("OSBootDiskOverrideWQL") & " ] ", LogTypeInfo
			For each oWMIDisk in AllDiskDrivesEx(oEnvironment.Item("OSBootDiskOverrideWQL"))

				'
				' Custom Processing here, add code to help select the OS Boot Disk.
				'    oWMIDisk is Win32_DiskDrive class.
				'

				If bFound = SUCCESS then
					oLogging.CreateEntry "Pass1: There is another disk that meets the Boot Criteria: " & oWMIDisk.Path_, LogTypeInfo
				Else
					oEnvironment.Item("OSDDiskIndex") = oWMIDisk.Index
					bFound = SUCCESS
				End if

			next
		End if

		''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
		'
		'  2nd pass - Use the 1st Partition larger than 15GB on the first disk with a bootable partition.
		'

		If bFound = FAILURE then
			oLogging.CreateEntry "No drive was found using search parameters, Use the 1st \Windows Partition found.", LogTypeInfo

			set oDiskPartBoot = GetBootDriveEx( false, oEnvironment.Item("ImageBuild"), false )
			If not oDiskPartBoot is nothing then 
				oEnvironment.Item("OSDDiskIndex") = oDiskPartBoot.Disk
				bFound = SUCCESS
			End if
		End if

		TestAndLog bFound = SUCCESS, "Verify OSDDiskIndex was found and set: " & oEnvironment.Item("OSDDiskIndex")
		Main = bFound

	End Function

End class

	</script>
</job>

Advertisement